Возьмем для примера код:

(define f

  (lambda (x) ... (display x) ...))

Значение переменной x необходимо только в выражении (display x) и в остальных частях процедуры не используется.

Пусть необходимо привести код к виду:

(define f

  (special-form-with-hidden-input ...  (display-hidden-input) ...))

В результате раскрытия второго варианта, должен получаться первый. При этом, имя входной переменной не имеет значения, так как скрыто, и генерируется автоматически с соблюдением гигиены.
Знаний, чтобы реализовать только средствами макросов, не хватает. Сделал несколько другим образом, проще:

(define param (make-parameter #f))

(define-syntax-rule (special-from-with-hidden-input a ...)

  (lambda (x)

    (parameterize ([param x])

      a ...)))

(define (display-hidden-input)

  (display (param)))

Но в решении используется параметр - по большому счету глобальная переменная.

Есть варианты лучше?

Если display-hidden-input - функция, то никак. Только через параметр. Если макрос - можно ввести анафору. Можно более конкретный пример, что требуется сделать?

Цитата

---

Kergan :
Если display-hidden-input - функция, то никак. Только через параметр. Если макрос - можно ввести анафору. Можно более конкретный пример, что требуется сделать?

---

Так и есть, если уходить от параметров, то display-hidden-input функцией никак быть не может.
Такой пример я привел, чтобы не усложнять. Более подробно: входной параметр - это продолжение. И хотелось бы что-то подобное:

(define (f switch-k)

  ...

  (let ([switch-k (let/cc k (switch-k k))])

    ...

    (let ([switch-k (let/cc k (switch-k k))])

      ...

      (f switch-k)))) ;в конце переход на начало цикла

привести к виду:

(define f

  (cycle-with-switching

   ...

   (switch)

   ...

   (switch)

   ...

   ))

Только какими средствами это сделать

2qaqa
Если предоставить клиентскому коду возможность работы с этой скрытой переменной, то запрет на невозможность переопределения внешним let-ом будет нарушать гигиену. Если клиенсткому коду эта переменная не нужна, то гигиеническая анафора подойдет. Как я понял, требуется реализовать dsl cycle-with, имеющий следующий синтаксис (cycle-with body ...+), body ::= racket-expression | cycle-with-clause, причем cycle-with-clause задает некоторое преобразование предыдущих форм и мы можем его дооопределять. Будет как-то так:

 

#lang racket

 

(require syntax/parse/define

         racket/stxparam

         racket/stxparam-exptime

         (for-syntax syntax/parse))

 

(provide cycle-with

         start

         call

         switch)

 

(module+ extras

         (provide cycle-with-hidden

                  define-cycle-with-clause))

 

(define-syntax-parameter cycle-with-hidden

  (lambda (stx) (raise-syntax-error 'anaphora "can be used only in cycle-with context" stx)))

 

(begin-for-syntax 

  (struct cycle-with-clause (transformer)

    #:property prop:procedure (lambda (stx) (raise-syntax-error #f "can be used only in cycle-with context" stx)))

 

  (define-syntax-class cycle-with-clause-class

    (pattern (x:id rest ...) 

             #:do [(define value (syntax-local-value #'x (lambda _ #f)))]

             #:when (cycle-with-clause? value)

             #:attr transformer (cycle-with-clause-transformer value))))

 

(define-simple-macro (define-cycle-with-clause name:id [pattern:expr res:expr] ...+)

  (define-syntax name (cycle-with-clause (syntax-parser [pattern res] ...))))

 

(define-syntax (cycle-with stx)

  (syntax-parse stx

    [(cycle-with c:cycle-with-clause-class r ...) ((attribute c.transformer) #'(c r ...))]

    [(cycle-with e:expr r:expr ...+) #'(begin e (cycle-with r ...))]

    [(cycle-with e:expr) #'e]))

 

(define-cycle-with-clause start

  [((start) r ...+) #'(lambda (param) 

                        (syntax-parameterize ([cycle-with-hidden (make-rename-transformer #'param)])

                          (cycle-with r ...)))])

 

(define-simple-macro (call name:id)

  (name cycle-with-hidden))

 

(define-cycle-with-clause switch

  [((switch) r:expr ...+) #'(let ([param (let/cc k (cycle-with-hidden k))])

                              (syntax-parameterize ([cycle-with-hidden (make-rename-transformer #'param)])

                                (cycle-with r ...)))])

 

если импортируется сам модуль, то доступа к скрытой переменной нет (ни на изменение ни на чтение), если импортируем extras - доступ есть (и на изменение и на чтение). Можно еще сделать варинат с доступом на чтение, но без доступа на изменение, однако в этом случае переменная все равно будет шадовиться let'ом (имеется ввиду cycle-with-hidden, a не tmp, tmp в любом лучае эффективно скрыта и получить к ней доступ никак нельзя).

2Kergan
Так как я c syntax/parse и с остальными неясными для меня вещами, присутствующими в примере, не разбирался еще, то понять сразу, что тут делается не получится. Одна только просьба, приведите небольшой пример того, как это должно использоваться
У меня в примере cycle-with-switching (это у вас короче называется cycle-with), должна раскрываться в лямбду, а если, пользуясь вашим кодом написать:

(cycle-with

 (display "HELLO!"))

, то осуществляется печать сразу.
А за примеры большое спасибо!

Цитата

---

(f switch-k)))) ;в конце переход на начало цикла

---

На начало текущего цикла? Можете привести развернутый пример?

Цитата

---

На начало текущего цикла? Можете привести развернутый пример?

---

Там имелось в виду, что f должна представлять собой бесконечный цикл, и поэтому в последней строке вызывает сама себя

2Kergan
Проверил, то что надо! Буду разбираться дальше

Цитата

---

Код с datum->syntax может себя иногда вести весьма нетривиально, так что подобных низкоуровневых преобразований следует по возможности избегать.

---

Вообще-то он обязан вести себя в соответствии со стандартом r6rs. Тем более, что это базовая вещь, которая используется повсеместно.

Цитата

---

Вообще-то он обязан вести себя в соответствии со стандартом r6rs. Тем более, что это базовая вещь, которая используется повсеместно.

---

ну так это поведение и есть иногда очень и очень нетривиально

Цитата

---

А где гарантия, что, например, rename-transformer будет вести себя тривиально(как ожидалось)?

---

ну мы верим что он реализован в соответствии со спецификацией. его нетривиальное поведение может быть разве что результатом бага, а вот нетривиальное поведение datum->syntax - идет из спецификации. Мы ведь берем контекст из объекта stx, но почему не из части этого объекта? тогда контексты будут разные. кроме того очень трудно проследить за контекстами, если это выражение попало сперва в один макрос, потом в другой, а сгенерировано было в третем макросе, который сам является результатом генерации четвертого

2Qaqa, вообще, если ограничиться конкретно тем что требуется, то можно мой код значительно упростить:

 

(define-syntax switch #f)

 

(define-syntax (with-cycle stx)

  (define (helper stx sym)

    (syntax-case stx (switch)

      [((switch) r rr ...) #`(let ([param (let/cc k (param k))]) 

                               #,(helper #'(r rr ...) sym))]

      [(r rr ...) #`(begin r #,(helper #'(rr ...) sym))]

      [() #`(#,sym param)]))

 

  (syntax-case stx ()

    [(_ id rest ...) #`(lambda (param) #,(helper #'(rest ...) #'id))]))

 

(define f 

  (with-cycle f

              (display 1)

              (display 2)

              (switch)

              (display 3)

              (display 4)

              (switch)

              (display 5)))

 

2Kergan
Ну и дублирование f, по хорошему, надо убирать, то есть еще один простенький макрос надо

Имхо, так более читабельно:

(with-cycle f

              (begin

               (display 1)

               (display 2))

              (switch

               (display 3)

               (display 4))

              (switch

               (display 5)))

чем

(with-cycle f

              (display 1)

              (display 2)

              (switch)

              (display 3)

              (display 4)

              (switch)

              (display 5))

2qaqa

Цитата

---

Ну, это относится и к трансформерам, т.к. есть вероятность что после трансформации контексты не будут совпадать.

---

да, именно так.между решениями две существенные разницы:
1. в первом случае используются синтаксические параметры, во втором - обычная переменная. Доступ к введенной макросом лексической переменной без нарушения гигиены позволяет обращаться к этой переменной только в рамках вызова текущего макротрансформера (как это и сделано во втором примере). Синтаксические параметры лишены этого ограничения - т.о. они могут обеспечивать взаимодействие _между_ вызовами, то есть связывать между собой различные макросы, в первом примере у нас много связанных макросов, во втором - всего один, и если мы попытаемся ввести другой макрос, который мог бы обращаться к скрытому параметру, то у нас со вторым примером не выйдет ничего, а с первым - не будет никаких затруднений, главное импортировать субмодуль extras.
2. в первом случае реализован "стандартный" механизм, позволяющий определять свои собственные формы (start/switch как раз и реализованы при его помощи) и макросы (как call), использующие скрытый параметр и переопределяющие его, это как раз обеспечивается благодаря первому пункту.

Цитата

---

2Kergan
Ну и дублирование f, по хорошему, надо убирать, то есть еще один простенький макрос надо

---

оно дублируется и в первом и во втором случае, т.к. f используется в контексте define и вне контекста with-cycle, то есть with-cycle о нем ничего не знает. Единственный способ решения этой проблемы - сделать макрос, который будет сразу раскрываться в define форму с внутренней формой with-cycle, какой-нибудь define-with-cycle то есть.